clear 
set more off

* Input data
input block pressure pct_no_flicks
1 8500 90.3
2 8500 89.2
3 8500 98.2
4 8500 93.9
5 8500 87.4
6 8500 97.9
1 8700 92.5
2 8700 89.5
3 8700 90.6
4 8700 94.7
5 8700 87.0
6 8700 95.8
1 8900 85.5
2 8900 90.8
3 8900 89.6
4 8900 86.2
5 8900 88.0
6 8900 93.4
1 9100 82.5
2 9100 89.5
3 9100 85.6
4 9100 87.4
5 9100 78.9
6 9100 90.7
end

* ANOVA 
anova pct_no_flicks pressure block

* Treatment means
tabstat pct_no_flicks, by(pressure) statistics(mean semean)

* Test linear hypotheses after ANOVA estimation
mat ycomp = (0,1,-1,0,0,0,0,0,0,0,0\ ///
             0,1,0,-1,0,0,0,0,0,0,0\ ///
             0,1,0,0,-1,0,0,0,0,0,0\ ///
             0,0,1,-1,0,0,0,0,0,0,0\ ///
             0,0,1,0,-1,0,0,0,0,0,0\ ///
             0,0,0,1,-1,0,0,0,0,0,0)
test, test(ycomp) mtest(noadjust)

* 1 vs. 2
anovacontrast pressure, values(1 -1 0 0)
* 1 vs. 3
anovacontrast pressure, values(1 0 -1 0)
* 1 vs. 4
anovacontrast pressure, values(1 0 0 -1)
* 2 vs. 3
anovacontrast pressure, values(0 1 -1 0)
* 2 vs. 4
anovacontrast pressure, values(0 1 0 -1)
* 3 vs. 4
anovacontrast pressure, values(0 0 1 -1)

* Diagnostic Case Statistics
predict predicted, xb
predict residual, res
predict leverage, leverage
predict student_res, rstud
predict cooksd, cooksd
list pct_no_flicks predicted residual leverage student_res cooksd

* Normal probability plot of residuals
qnorm residual

* Plot of residuals versus predicted values
scatter residual predicted

* Plot of residuals by extrusion pressure (treatment)
scatter residual pressure

* Plot of residuals by batch of resin (block)
scatter residual block